goto %1 main



:main
set lockdir=%~n0.lock
set sleep=^>nul ping 127.0.0.1 -n
set install=start "Installer" "%~nx0" install
:: set install=cmd /c "%~nx0" install

set urlroot=https://fpdownload.macromedia.com/pub/flashplayer
set verxml=masterversion.xml
wget --no-check-certificate -N "%urlroot%/masterversion/%verxml%"

call :release
for /f "tokens=2 delims=[]" %%A in ('ver') do ^
for /f "tokens=2,3 delims=. " %%B in ("%%A") do ^
set /a ver=%%B*100+%%C
if /i %ver% lss 602 (
	%install% ActiveX_win active_x
	%sleep% 5
)
%install% NPAPI_win plugin
%sleep% 5
%install% PPAPI_winchrome ppapi
%sleep% 5
goto :eof



:install
for /f "delims=" %%A in ('find /i "%2 version=" ^<"%verxml%"') do ^
for /f "tokens=2 delims==/" %%B in ("%%A") do ^
for /f "tokens=1-4 delims=," %%C in ("%%~B") do (
	set v1=%%C
	set v2=%%D
	set v3=%%E
	set v4=%%F
	goto found
)
exit



:found
set msi=install_flash_player_%v1%_%3.msi
wget --no-check-certificate -N "%urlroot%/pdc/%v1%.%v2%.%v3%.%v4%/%msi%"
call :lock
title Installing %msi%...
start /wait msiexec /i "%msi%" /passive /norestart
call :release
exit



:lock
@mkdir %lockdir% 2>nul && goto :eof
@%sleep% 3
@goto :lock



:release
@del /f /q %lockdir%
@rmdir /s /q %lockdir%