#!/usr/bin/perl
use v5.35.0;

# Slurp the whole map as a single string, regularize its
# line terminators, work out how big it is, and set up deltas
# for moving one step in each of the four available directions

local $/ = undef;
local $_ = <>;
s/\v+/\n/g;
my $row = 1 + index $_, "\n";
my $len = length;
my @dp = (1, -$row, -1, $row);

# Find the guard's starting position and direction

/([>^<v])/g;
my $start_pos = (pos) - 1;
(my $start_dir = $1) =~ tr/>^<v/0123/;

# Bitwise encodings for map cells, ASCII assumed
#
# 0000xxxx - map edge
# 0010xxxx - free passage
# 0100xxxx - permanent obstacle
# 0110xxxx - proposed obstacle
# xxxx1xxx - entered going south (dir = 3)
# xxxxx1xx - entered going west (dir = 2)
# xxxxxx1x - entered going north (dir = 1)
# xxxxxxx1 - entered going east (dir = 0)
#
# If an obstacle gets entered from the same direction twice,
# it's part of a loop.

s/#/\x40/g; s/[>^<v.]/\x20/g;	# Bitwise encode map

my $loops = 0;

for my $obs_pos (0 .. $len - 1) {

	# Only propose obstacles in free cells
	next unless vec($_, $obs_pos, 8) == 0x20;
	vec($_, $obs_pos, 8) = 0x60;
	
	my $pos = $start_pos;
	my $dir = $start_dir;

	for (;;) {
		$pos += $dp[$dir];	# Advance

		# Done if edge hit
		last unless 0 <= $pos < $len;
		my $cell = vec($_, $pos, 8);
 		last if $cell < 0x10;
		
		if ($cell & 0x40) {	# Obstacle?
			my $dirbit = 1 << $dir;
			if ($cell & $dirbit) {	# Loop?
				++$loops;
				last;
			} else {
				vec($_, $pos, 8) |= $dirbit;	# Mark it
				$pos -= $dp[$dir];		# Retreat
				$dir = ($dir - 1) & 3;		# Turn right
			}
		}
	}

	s/[\x41-\x4f]/\x40/g;		# Reset permanent obstacles
	s/[\x21-\x2f\x60-\x6f]/\x20/g;	# Clean route and temp obstacles
}

say $loops;